circuito con retardo

Tema en 'R/C ELECTRÓNICA' iniciado por sito, 26 Dic 2009.

  1. sito Gurú FPV

    sito
    Registrado:
    28 Feb 2009
    Mensajes:
    3.726
    Me Gusta recibidos:
    0
    bueno os planteo una pregunta que me seria de gran alluda que me pudieseis resolver,ya que tengo en mente desde hace tiempo hacer, para el cual necesito un circuito que tenga un pequeño retardo.

    me esplico la idea es alimentar un circuito con el voltaje que sea, maximo 12 voltios y que este circuito cuando apagemos la emisora, tenga un retardo de unos 2 a3 segundos hasta activar un servo para abrir una trampilla del avion.

    si alguien conoce algun circuito o alguna solucion me seria de gran alluda,



    muchas gracias anticipadas
     
  2. miquel.s.m Gurú FPV

    miquel.s.m
    Registrado:
    22 Mar 2007
    Mensajes:
    3.610
    Me Gusta recibidos:
    0
    si te vale, yo tengo un mini circuito para tren retractil.
    activas el canal y un servo rapido y despues el otro lento, o si lo necesitas al reves.
    buscare el esquema para el pic 12c508, es sencillisimo.
    pasa que solo encuentro el de otro pic.

    los hex los tengo
     

    Adjuntos:

    • LG_675.jpg
      LG_675.jpg
      Tamaño de archivo:
      25,6 KB
      Visitas:
      187
    • LG_V4.jpg
      LG_V4.jpg
      Tamaño de archivo:
      6,5 KB
      Visitas:
      1.037
  3. SantiagoBG Miembro

    SantiagoBG
    Registrado:
    15 Jun 2009
    Mensajes:
    276
    Me Gusta recibidos:
    0
    Hola Sito.

    Electronicamente yo veo un operacional configurado como comparador que compare una tension de referencia con la tension RSSI del receptor; cuando baje de x tension que active un 555 con un retardo X para que de tension a su salida, pero luego queda transformar esa tensión en un tren de impulsos que lo entienda un servo....complicado.

    Creo que la solucion es un PIC y hacer un programa para todo esto.

    Otra es buscar un retardador de servos!!!!!! que se active la señal por FS en el receptor y un PIC que meta un retardo para modificar el ancho de los pulsos. Si desaparece la señal por FS, el temporizador se deberia de anular. Esto creo que te lo comenta miquel con lo del tren retractil.

    Un saludo, Santiago.
     
  4. miquel.s.m Gurú FPV

    miquel.s.m
    Registrado:
    22 Mar 2007
    Mensajes:
    3.610
    Me Gusta recibidos:
    0
    aqui la funcion, el link del creador ya no funciona, pero este se puede modificar al gusto:


    LIST P=12F675,R=HEX
    ;
    ; Retractable Landing Gear CONTROLLOR FOR R/C airccraft
    ; SUN, PU-NENG
    ;
    ; VERSION 4.0 (FEB/19/2005)
    ; ADD ONE MORE SERVO TO CONTROL LANDING-GEAR CABIN DOOR
    ;
    ; VERSION 3.0 (MAY/05/2004)
    ; END POINTS ADJUSTABLE, FOR HIGH-END LIKE FUTABA FF8, JR 9X
    ; DTIME * 2SEC = TIME TO MOVE FROM SIDE TO SIDE
    ;
    ; CHIP CONFIG : INTERC, WDT OFF TO AVOID SERVOS CONFLICT.
    ;
    ;
    ; DEFINE RAM
    ;----- SYSTEM ---------
    TMR0 EQU 1 ;TIMER 0
    PCL EQU 2 ;PROGRAM COUNTER
    STATUS EQU 3
    FSR EQU 4 ;BUFFER OF INDIRECT ADDR
    GPIO EQU 5
    OPTION_reg EQU 0x81
    TRISIO EQU 0x85
    OSCCAL EQU 0x90
    RP0 EQU 5
    CMCON EQU 0x19 ;CMCON REGISTER
    ANSEL EQU 0x9F ;ANALOG SEL
    CM0 EQU 0
    CM1 EQU 1
    CM2 EQU 2
    ;
    ;
    ;---- USER registers DEFINE ------
    ;
    TMR2 EQU H'21' ;
    TMR3 EQU H'22' ;PWM WIDTH, INPUT
    TMR4 EQU H'23' ;
    POINT EQU H'24' ;CURRENT POSITION
    DELAY EQU H'25' ;DALEY
    POINT2 EQU H'26' ;SERVO2 POSITION
    ;
    ;---- USER FLAGS IN FLAGR DEFINE ------
    ;
    ;---- VARIABLES DEFINE ----
    ;
    W EQU 0 ;d VALUE FOR INCF......
    F EQU 1 ;d VALUE
    NOISE EQU D'80' ;PULSE LESS THEN THIS DEFINE AS NOISE, 0.8mS
    T5 EQU D'25' ;25 X 20mS =0.5S, HALF OF ACSL FLASH TIME ***
    DTIME EQU D'03' ;DTIME X 2SEC =6 SEC, RUN FROM SIDE TO SIDE
    RLIMIT EQU D'180' ;INPUT PWM > 170 = OPEN
    LLIMIT EQU D'120' ;INPUT PWM < 130 = CLOSE
    INITPOSI EQU D'110' ;INITIAL POSITION OF GEAR
    OPENPOSI EQU D'200' ;OPEN POSITION OF SERVO 2
    CLOSEPOSI EQU D'100' ;CLOSE POSITION OF SERVO 2
    ;
    ;---- HARDWARE PINS DEFINE ----

    INPIN EQU 3 ;RB0 AS INPUT PORT
    OUTPIN EQU 2 ;RB2 AS OUTPUT PORT
    ACSL1 EQU 0 ;Anti-Collision Strobe Light, FLASH
    ACSL2 EQU 1 ;INVERT OF ACSL1
    LL1 EQU 4 ;Landing Lights ON/OFF ACTION***
    SERVO2 EQU 5 ;CABIN DOOR
    ;
    ;---- SYSTEM CONFIG ----
    __CONFIG H'3F84' ;_INTRC_OSC_NOCLKOUT,WDT OFF,PWRTE ON
    ;
    ;
    ;
    ;
    ;
    ;========== MAIN PROGRAM =========
    ;------------------------------------
    ;INPUT PARAMETERS,
    ;TEMP REGISTERS
    ;OUTPUT PARAMETERS
    ;------------------------------------
    ;--- RESTORE OSC CALIBRATION ---------

    ORG 0
    BSF STATUS,RP0 ;;BANK1
    CALL 3FFh
    MOVWF OSCCAL ;RESTORE OSC CALI
    ;----------------------------------

    START
    CALL INIT_SYS


    ;----------------------------------------
    ;TMR3,NOISE,RLIMIT,LLIMIT
    ;
    ;
    ;---------------------------------------

    MAIN
    CALL GET_PWM

    MOVLW NOISE
    SUBWF TMR3,W
    SKPC ;IF f > w, C= 1,SKIP
    GOTO MAIN ;ELSE IT'S NOISE, NO OUTPUT


    MOVLW RLIMIT ;LOAD CURRENT POINT
    SUBWF TMR3,W
    SKPNC ;IF TMR3 f > w, C=1
    CALL OPEN ;IF TMR3 f < w, C=0,

    MOVLW LLIMIT ;LOAD CURRENT POINT
    SUBWF TMR3,W
    SKPC ;IF TMR3 f > w, C=1,
    CALL CLOSE ;IF TMR3 f < w, C=0

    CALL OUT_PUT
    GOTO MAIN


    ;=====================================


    ;------- INIT_SYS ----------------------
    ;T5,DTIME
    ;
    ;TMR4, DELAY, POINT, POINT2
    ;---------------------------------------

    INIT_SYS
    MOVLW 8 ;PA3=INPUT, OTHERS =OUTPUT
    MOVWF TRISIO
    MOVLW H'C0' ;T0CS=0, TO ENABLE GP2
    MOVWF OPTION_reg
    CLRF ANSEL ;Turn off ADC on the 12F675 - All pins digital
    BCF STATUS,RP0 ;BANK0
    BSF CMCON,CM2 ;turn the input pins back to digital
    BSF CMCON,CM1
    BSF CMCON,CM0
    CLRF GPIO ;SET ALL OUTPUT LOW ***

    MOVLW INITPOSI ;INITIAL POSITION OF GEAR
    MOVWF POINT
    MOVLW OPENPOSI ;INITIAL POSITION OF CABIN DOOR
    MOVWF POINT2
    MOVLW DTIME
    MOVWF DELAY
    MOVLW T5 ;RESTORE TMR4
    MOVWF TMR4
    RETURN
    ;---------------------------------------------










    ;-------GET INPUT PWM FROM INPIN ------------
    ;GPIO_INPIN
    ;
    ;TMR3
    ;---------------------------------------

    GET_PWM
    BTFSS GPIO,INPIN ;IF INPIN = HIGH, INCREASE TMR3
    GOTO GET_PWM
    CLRF TMR3 ;READ INPIN PULSE WEITH

    GET_PWM2
    INCF TMR3,F ;START LOOP
    NOP
    NOP ;10 uS LOOP
    NOP
    NOP
    NOP
    NOP
    BTFSC GPIO,INPIN ;UNTIL INPIN GO LOW
    GOTO GET_PWM2 ;END LOOP
    RETURN
    ;-----------------------------------------------










    ;------- OPEN CABIN & RELEASE THE LANDING GEAR ------------
    ;TMR3,POINT,DTIME,OPENPOSI, CLOSEPOSI
    ;DELAY
    ;POINT,POINT2
    ;-----------------------------------------------

    OPEN MOVLW OPENPOSI
    MOVWF POINT2
    BSF GPIO,LL1 ;LANDING LIGHT ON
    ;---------------------
    DECFSZ DELAY,F
    RETURN
    MOVLW DTIME
    MOVWF DELAY
    ;---------------------
    MOVF POINT,W ;LOAD CURRENT POINT
    SUBWF TMR3,W
    SKPNZ ;IF f = w, Z=1,NO SKIP
    RETURN
    SKPC ;IF TMR3 f > POINT w, C=1, SKIP
    GOTO OPEN2 ;IF f < w, C=0,
    INCF POINT,F
    RETURN

    OPEN2 DECF POINT,F
    RETURN
    ;----------------------------------









    ;------- CLOSE CABIN & RETRIEVE THE LANDING GEAR ------------
    ;TMR3,POINT,DTIME,OPENPOSI, CLOSEPOSI
    ;DELAY
    ;POINT,POINT2
    ;-----------------------------------------------
    CLOSE DECFSZ DELAY,F
    RETURN
    MOVLW DTIME
    MOVWF DELAY
    ;---------------------
    MOVF POINT,W ;LOAD CURRENT POINT
    SUBWF TMR3,W
    SKPNZ ;IF f = w, Z=1,NO SKIP
    GOTO CLOSE3
    SKPC ;IF TMR3 f > POINT w, C=1, SKIP
    GOTO CLOSE2 ;IF f < w, C=0,
    INCF POINT,F
    RETURN

    CLOSE2 DECF POINT,F
    RETURN

    CLOSE3 MOVLW CLOSEPOSI
    MOVWF POINT2
    BCF GPIO,LL1 ;LANDING LIGHT OFF
    RETURN
    ;---------------------------------------








    ;------- OUTPUT ------------
    ;POINT, POINT2,T5
    ;TMR2,TMR4
    ;GPIO_OUTPIN,GPIO_SERVO2,GPIO_ACSL1,GPIO_ACSL2,
    ;---------------------------------------
    OUT_PUT BSF GPIO,OUTPIN ;PULL OUTPIN HIGH
    MOVF POINT,W ;
    MOVWF TMR2
    K3 NOP
    NOP
    NOP
    NOP
    NOP
    NOP
    NOP ;MAKE THIS LOOP 10 uS
    DECFSZ TMR2,F
    GOTO K3 ;END OF LOOP
    BCF GPIO,OUTPIN ;PULL PULSE LOW
    ;---------------------------
    BSF GPIO,SERVO2 ;PULL OUTPIN HIGH
    MOVF POINT2,W ;
    MOVWF TMR2
    K4 NOP
    NOP
    NOP
    NOP
    NOP
    NOP
    NOP ;MAKE THIS LOOP 10 uS
    DECFSZ TMR2,F
    GOTO K4 ;END OF LOOP
    BCF GPIO,SERVO2 ;PULL PULSE LOW


    ;-------FLASH ASCL

    K5 DECFSZ TMR4,F ;
    RETURN
    MOVLW T5 ;RESTORE TMR4
    MOVWF TMR4
    BTFSS GPIO,ACSL1
    GOTO K6 ;LSTA=0
    BCF GPIO,ACSL1 ;LSTA=1
    BSF GPIO,ACSL2
    RETURN
    K6 BSF GPIO,ACSL1 ;LSTA=0
    BCF GPIO,ACSL2
    RETURN

    ;---------------------------------------------------
    END
     
  5. Fred Gurú FPV

    Fred
    Registrado:
    26 Jun 2008
    Mensajes:
    3.659
    Me Gusta recibidos:
    1
    Un simples FS (Chino a 3.5€) no te sirve para esto ? creo que solo se activa después de unos segundos...
     
  6. sito Gurú FPV

    sito
    Registrado:
    28 Feb 2009
    Mensajes:
    3.726
    Me Gusta recibidos:
    0
    muchas gracias compañeros, no he podido contestar antes por temas de trabajo,

    concretamente este circuito lo necesito, para la electronica de sistema de lanzamiento de paracaidas, ya que probamos con un canal todo o nada de la emisora y funciono a la perfeccion, lo podeis ver en el hilo de paracaidas.

    entonces la idea es que para dar seguridad ha nuestros aeromodelos no vendria mal incorporar un paracaidas, por seguridad frente ha daños ha terceros, por lo tanto el retardo del circuito hace falta, frente ha una pequeña interferencia que no se dispare, pero si es prolongada si, si existe un fail safe con retardo yo creo que podria mirarse haber si se podria ajustar ha la demanda que necesito.


    alguno sabe donde lo venden????
     
  7. Fred Gurú FPV

    Fred
    Registrado:
    26 Jun 2008
    Mensajes:
    3.659
    Me Gusta recibidos:
    1
    Y que tal 2 FS en serie ?, si cada uno tiene su retardo ...:biggrin:
     
  8. sito Gurú FPV

    sito
    Registrado:
    28 Feb 2009
    Mensajes:
    3.726
    Me Gusta recibidos:
    0

    hombre pues no es tan mala idea:laugh::laugh::laugh::laugh:


    alguno sabe cuanto retardo tiene un fail safe y si se puede cual en concreto???


    muchas gracias y feliz 2010
     
  9. Miniplanes Miembro Activo

    Miniplanes
    Registrado:
    28 Mar 2007
    Mensajes:
    1.747
    Me Gusta recibidos:
    0
    Mira esto http://www.sussex-model-centre.co.uk/shopexd.asp?id=1408

    saludos
     
  10. sito Gurú FPV

    sito
    Registrado:
    28 Feb 2009
    Mensajes:
    3.726
    Me Gusta recibidos:
    0

    excelente aportacion miniplanes,


    si no lo he entendido mal, el temporizador tendria que ir con un circuito fail safe, cuando este actue y mande señal, el circuito retarda el movimiento del servo no????

    y si ha sido una interferencia larga y recupero radio antes del tiempo de temporizacion, supuestamente el circuito no deveria actuar, o tiene memoria?????


    feliz año para portugal tambien
     
  11. Miniplanes Miembro Activo

    Miniplanes
    Registrado:
    28 Mar 2007
    Mensajes:
    1.747
    Me Gusta recibidos:
    0
    Hola, pues hay que testar-lo primero, pero pienso que lo que quieres es una otra cosa, quieres un circuito temporizador y no retardador, es asi ?

    saludos
     
  12. fbforos Miembro

    fbforos
    Registrado:
    1 Nov 2008
    Mensajes:
    984
    Me Gusta recibidos:
    0
    Sito,

    lo primero que te tienes que plantear es como quieres que funcione. Y después a buscar. Tienes Failsafe en el receptor?, si es asi lo mejor es cogerlo a uno de los canales de failsafe, si no tienes failsafe, la cosa se te complicará bastante y tendras que chequear la trama ppm en el receptor para saber cuando desaparece. El problema viene cuando tienes una interferencia provocada por estar 2 en el mismo canal. Entonces no hay nada que hacer seguramente no se te activará
     
  13. sito Gurú FPV

    sito
    Registrado:
    28 Feb 2009
    Mensajes:
    3.726
    Me Gusta recibidos:
    0
    intento esplicarlo mejor, si tengo fail safe con la wfly 09.

    la idea es, equipar el avion con paracaidas para evitar sustos o daños mayores, por lo tanto para que el paracaidas salga tengo un servo que abre la trampilla del alojamiento del paracaidas y asi este sale.
    pues bien necesito un circuito que me permita abrir esta trampilla cuando el avion se quede sin radio, pero ojo y hay va lo del retardo, si la interferencia es pequeña y se puede volver a recuperar el control no me interesa que se abra, pero si la perdida de mando es considerable, 3a5 segundos ya es mas probable que no se recupere el control, por lo tanto en esta ultima opcion si que me interesa que se abra el paraca, de hay preguntar que si habia fail safe y se recuperaba mando, si el circuito de miniplanes anulaba la temporizacion para que no se abra al recuperar mando antes de esos 3a5 segundos
     
  14. fbforos Miembro

    fbforos
    Registrado:
    1 Nov 2008
    Mensajes:
    984
    Me Gusta recibidos:
    0
    Ese circuito lo que hace es ralentizar el recorrido del servo en una dirección o en la otra.
    Tienes que tener en cuenta que el servo se comenzará a mover tan pronto como pierdas el control y tardará el tiempo programado en hacer el recorrido completo. Luego depende de como tengas colocado el pestillo para que salte antes o después.
    Si por cualquier razón recuperas el control el servo comenzará a moverse en dirección contraria lentamente.
     
  15. sito Gurú FPV

    sito
    Registrado:
    28 Feb 2009
    Mensajes:
    3.726
    Me Gusta recibidos:
    0
    el servo con el que se hicieron las pruebas estaba conectado a un canal todo o nada con un recorrido de 90º
     
  16. fbforos Miembro

    fbforos
    Registrado:
    1 Nov 2008
    Mensajes:
    984
    Me Gusta recibidos:
    0
    Siempre que no sea un servo de tren de aterrizaje que no tiene más que 2 posiciones, el resto de los servos gira en una dirección lentamente y si no ha llegado al final del recorrido y cambiamos la señal comienza a girar en la otra dirección.
     
  17. Miniplanes Miembro Activo

    Miniplanes
    Registrado:
    28 Mar 2007
    Mensajes:
    1.747
    Me Gusta recibidos:
    0
    Hola, pues lo mejor que si puede hacer es analisar la señal de Rssi y actuar el paracaidas si la señal de recepcion si pierde por mas de 5 segundos, si puede conseguir un circuito con un NE555 pero eso va a llevar algun tiempo.

    saludos
     
  18. supercanii Moderator

    supercanii
    Registrado:
    12 Mar 2008
    Mensajes:
    4.408
    Me Gusta recibidos:
    0
    Supongo que en tu setup el arduino/ardupilot (esos mini ordenadores) no lo llevas no.? porque con el programación mediante puedes hacer lo que quieres y quieras... yo optaria por él, aparte en un furuto te puede servir para otras cosas, cosa que un ciruito específico es para lo que fué diseñado y listo...

    Saludos,
    Sergio.
     
  19. fitozgz Gurú FPV

    fitozgz
    Registrado:
    7 Ago 2008
    Mensajes:
    6.045
    Me Gusta recibidos:
    1
    Creo que para el invento seria necesario un sistema aparte, que funcionara con una pila aparte. Debería funcionar además de si falla la recepción, por falta de batería principal o de video. Por lo que creo que debe de ser un sistema dedicado con su propia alimentación.
     
  20. sito Gurú FPV

    sito
    Registrado:
    28 Feb 2009
    Mensajes:
    3.726
    Me Gusta recibidos:
    0
    para empezar he pedido un circuito de fail safe, cuando lo reciba lo destripare y empezare ha toquiñear haver si sacamos algo claro de esta manera, ya que seria una opcion mas bien baratilla.

    sigo escuchando opciones, no descarto probar lo del circuito del ardupilot
     
  21. supercanii Moderator

    supercanii
    Registrado:
    12 Mar 2008
    Mensajes:
    4.408
    Me Gusta recibidos:
    0
    En eso tienes razón ya que si falla la alimentación del receptor no tendría tensión para alimentar el circuito y el servo de apertura... en el caso de que sea el video el piloto desde tierra podría activar el paracaídas pero si vamos a dar seguridad completa tendría que ser un sistema autónomo o que pudiera trabajar indistintamente con la batería del receptor o la de video según sea el caso... eso se podría hacer con algún "relé" que si no llega energía desde la batería del receptor conmutara a la de video... por decir y tirar una idea...

    Saludos,
    Sergio.
     
  22. sito Gurú FPV

    sito
    Registrado:
    28 Feb 2009
    Mensajes:
    3.726
    Me Gusta recibidos:
    0
    nose aun como sera o actuara el fail safe, pero el circuito como bien decis esta pensado con alimentacion aparte, lo del sistema que se abra con la perdida de voltaje esta solucionado, pila aparte un rele que este alimentado con 5v del receptor, y la pila suplementaria conectada al contacto n/c (normalmenta cerrado)y alservo, de manera que al tener tension el rele se quede en el contacto n/a (normalmente abierto) y si se quema el variador o falla la bateria, el rele se queda sin tension y buelve ha su posicion original (n/c) activando asi con la pila aparte el servo, que teoricamente el servo, cerrado el compartimento, este descentrado y al irse el voltage y aplicarle los 5v sin señal alguna este tiende ha centrarse abriendo asi el compartimento (mas o menos como el centrado del servo del sistema del lince) cuando le das tension gira hasta su centro mecanico


    no se si me he esplicao bien, perdonad si no es asi:redface2:
     
  23. Fred Gurú FPV

    Fred
    Registrado:
    26 Jun 2008
    Mensajes:
    3.659
    Me Gusta recibidos:
    1
    Tambien vas necesitar FS para el motor para tener certeza que esta a 0 cuando se abre el paracaidas, no?
     
  24. sito Gurú FPV

    sito
    Registrado:
    28 Feb 2009
    Mensajes:
    3.726
    Me Gusta recibidos:
    0
    seria lo sullo, pero eso no me quita el sueño, ya que en las pruevas hechas, el paracaidas abierto y el avion con motor, cae a la misma velocidas que sin motor, lo unico que con motor no hace mas que dar vueltas sobre el eje del paraca
     
  25. fbforos Miembro

    fbforos
    Registrado:
    1 Nov 2008
    Mensajes:
    984
    Me Gusta recibidos:
    0
    Y un Ardupilot que te lo lleve a casa y te abra el paracaidas cuando este encima del campo si no hay señal de radio y la batería está por debajo de un determinado voltaje.

    Además puedes poner un sensor barométrico por si fallan las pilas de la alimentación del motor, conectado al ardupilot, si no hay señal de radio y además está por debajo de 100mtos pos paracaidas al canto. Como funciona el vuelta a casa el parato estará estabilizado, cuanto mas se acerque más fácil será el recuperarlo.

    El problema es que todo esto es más peso, y cuanto más carga alar peor vuela y más problemas.

    Si lo que buscas es solucionar el problema de la radio, un vuelta a casa puede ser lo más seguro.
     
  26. Fred Gurú FPV

    Fred
    Registrado:
    26 Jun 2008
    Mensajes:
    3.659
    Me Gusta recibidos:
    1
    Lo que necesitas es esto :laugh: :
     

    Adjuntos:

  27. sito Gurú FPV

    sito
    Registrado:
    28 Feb 2009
    Mensajes:
    3.726
    Me Gusta recibidos:
    0


    si es verdad un buelta ha casa esta pensado para eso, pero hay que varajar la opcion de que se queme el variador, que ami ya me paso una vez, si se quema adios ha todo, ya no lo puedes traer, aunque es una idea excelente, la idea es hacer un sistema varato y efectivo que todos se lo puedan permitir sin gastar grandes cantidades de dinero, y para los que de programacion no entienden, lo tengan mas facil, bamos un sistema touch and go
     
  28. sito Gurú FPV

    sito
    Registrado:
    28 Feb 2009
    Mensajes:
    3.726
    Me Gusta recibidos:
    0



    :ansioso::ansioso::ansioso::ansioso:

    y donde meto eso?????
    y la bomba de inchado que lleva en un ala me hara cosas raras????
    y cuanto tarda en incharlos???
    sera como las chalecos salvavidas tiras de la cuerda y en cero coma se incha??????

    :laugh::laugh::laugh::laugh::laugh::laugh::laugh::locos::locos::locos:
     
  29. tintin Maestro FPV

    tintin
    Registrado:
    29 Mar 2009
    Mensajes:
    2.737
    Me Gusta recibidos:
    0
    eso parece un racimo de....ALMORRANAS!!!!!:icon_twisted::icon_twisted::icon_twisted:
    de todas formas, si te empeñas, sito, seguro que le encuentras sitio... :tongue2::tongue2::tongue2:
     

Compartir esta página